fungsi MAXIFS

Mengembalikan nilai sel maksimum dalam rentang yang memenuhi beberapa kriteria dalam beberapa rentang.

tip

This function is available since LibreOffice 5.2


Sintaksis

MAXIFS(Func_Range; Range1; Kriteria1 [; Range2; Kriteria2 [; ...]]))

Func_Range – argumen yang dibutuhkan. Rentang sel, nama dari rentang yang dinamai atau label kolom atau baris yang berisi nilai untuk menghitung maksimum.

Criterion1 - argumen yang diperlukan. Ekspresi string yang mewakili kondisi logis atau referensi sel untuk ekspresi string tersebut. Ekspresi dapat berisi teks, angka, ekspresi reguler, atau wildcard (jika diaktifkan dalam opsi penghitungan ).

Range2 - Opsional. Range2 dan semua yang berikut memiliki arti yang sama dengan Range1.

Criterion2 - Opsional. Criterion2 dan semua yang berikut memiliki arti yang sama dengan Criterion1.

Ikon Peringatan

Func_Range dan Range1, Range2 ... harus memiliki ukuran yang sama, jika tidak fungsi mengembalikan err: 502 - Argumen tidak valid.


Ikon Catatan

Hubungan logis antara kriteria dapat didefinisikan sebagai logika AND (kata hubung). Dengan kata lain, jika dan hanya jika semua kriteria yang diberikan terpenuhi, nilai dari sel yang sesuai dari Func_Range yang diberikan diperhitungkan.


Fungsi ini dapat memiliki hingga 255 argumen, artinya Anda dapat menentukan 127 rentang kriteria dan kriteria untuknya.

Ikon Peringatan

Jika sel berisi TRUE, itu diperlakukan sebagai 1, jika sel berisi FALSE - sebagai 0 (nol).


Ikon Catatan

Fungsi ini adalah bagian dari Open Document Format untuk Aplikasi Perkantoran (OpenDocument) Versi 1.2. (ISO/IEC 26300:2-2015)


Contoh

Pertimbangkan tabel berikut

A

B

C

1

Nama Produk

Penjualan

Pendapatan

2

pensil

20

65

3

pena

35

85

4

notebook

20

190

5

buku

17

180

6

kotak pensil

tidak

tidak


Ikon Peringatan

Dalam semua contoh di bawah ini, rentang untuk perhitungan mengandung baris #6, yang diabaikan karena mengandung teks.


Penggunaan sederhana

=MAXIFS(B2:B6;B2:B6;"<35")

Menghitung nilai maksimum dari rentang B2:B6 yang lebih besar dari atau sama dengan 20. Pengembalian 35. Baris kelima tidak memenuhi kriteria.

=MAXIFS(C2:C6;B2:B6;">=20";C2:C6;"<90")

Menghitung nilai maksimum rentang C2:C6 yang lebih rendah dari 90 dan sesuai dengan sel rentang B2:B6 dengan nilai lebih besar dari atau sama dengan 20. Mengembalikan 85, karena baris keempat dan kelima tidak memenuhi setidaknya satu kriteria.

Menggunakan ekspresi reguler dan fungsi bersarang

=MAXIFS(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Menghitung nilai maksimum rentang C2:C6 yang sesuai dengan semua nilai rentang B2:B6 kecuali minimum dan maksimum. Mengembalikan 190, karena hanya baris keempat yang memenuhi kriteria.

=MAXIFS(C2:C6;A2:A6;"pen.*";B2:B6;"<="&MAX(B2:B6))

Menghitung nilai maksimum rentang C2:C6 yang sesuai dengan semua sel rentang A2:A6 yang dimulai dengan "pena" dan ke semua sel rentang B2:B6 kecuali maksimumnya. Mengembalikan 85, karena hanya baris ketiga yang memenuhi semua kriteria.

Referensi ke sel sebagai kriteria

Jika Anda perlu mengubah kriteria dengan mudah, Anda mungkin ingin menentukannya di sel yang terpisah dan menggunakan referensi ke sel ini dalam kondisi fungsi MAXIFS. Misalnya, fungsi di atas dapat ditulis ulang sebagai berikut:

=MAXIFS(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

If E2 = "pena", fungsi mengembalikan 65, karena referensi ke sel diganti dengan kontennya.